ISBLANK function

ISBLANK (Value) ISBLANK (Value)

Value

The value to check.

Returns

Logical Logical

Whether the given value is blank.

Returns whether the given value is blank. ISBLANK ( BLANK ()) ISBLANK ( BLANK ()) returns TRUE.

Related functions

IFBLANK is a convenient way of returning a different value if a value is blank, or the value itself otherwise. This formula returns Value1 if it isn't blank, and 0 otherwise:

IFBLANK (Value1, 0)

IFBLANK (Value1; 0)

To check if a value is not blank, use the ISDEFINED function. Use the BLANK function to create a blank value.

ISBLANK and arrays

Applying ISBLANK to an array yields a logical array with the same size as the original array, where TRUE elements indicate that the corresponding element in the original array is blank and FALSE elements indicate the opposite.

This formula returns { TRUE, FALSE }{ TRUE; FALSE }, indicating that the first element is blank and the second element is not:

ISBLANK ({ BLANK (), 42 })

ISBLANK ({ BLANK (); 42 })

Use AND to determine if all array elements are blank. This formula returns FALSE, as not all elements are blank:

AND ( ISBLANK ({ BLANK (), 42 }))

AND ( ISBLANK ({ BLANK (); 42 }))

Use OR to determine if one or more array elements are blank. This formula returns TRUE, as the first array element is blank:

OR ( ISBLANK ({ BLANK (), 42 }))

OR ( ISBLANK ({ BLANK (); 42 }))

Examples

ISBLANK ( BLANK ())

Returns TRUE.

ISDEFINED ( BLANK ())

Returns FALSE. Values which are not blank are defined, by definition.

IFBLANK (Value1, 0)

IFBLANK (Value1; 0)

Returns Value1 if it isn't blank, and 0 otherwise.

ISBLANK ({ 4, "test", BLANK () })

ISBLANK ({ 4; "test"; BLANK () })

Returns the array { FALSE, FALSE, TRUE }{ FALSE; FALSE; TRUE }, indicating that only the last element of the array is blank.

{ 4, "test", BLANK () } == BLANK ()

{ 4; "test"; BLANK () } == BLANK ()

Returns FALSE, as the array { 4, "test", BLANK () }{ 4; "test"; BLANK () }, in and of itself, is not blank.

! ISEMPTY ( FILTER ({ 4, "test", BLANK () }, ISBLANK (Element)))

! ISEMPTY ( FILTER ({ 4; "test"; BLANK () }; ISBLANK (Element)))

Returns TRUE, as the array { 4, "test", BLANK () }{ 4; "test"; BLANK () } contains at least one blank element. FILTER returns an array containing the only blank value, { BLANK () }{ BLANK () }. ISEMPTY, when applied to this array, returns FALSE to indicate that the array is not empty. The ! operator finally negates that return value, turning TRUE to FALSE and FALSE to TRUE.

OR ({ 4, "test", BLANK () } = BLANK ())

OR ({ 4; "test"; BLANK () } = BLANK ())

Returns TRUE, as the array { 4, "test", BLANK () }{ 4; "test"; BLANK () } contains at least one blank element. The = operator returns the array { FALSE, FALSE, TRUE }{ FALSE; FALSE; TRUE }, indicating that the first two elements are not blank, unlike the third element. OR finally returns TRUE, as there is at least one element in the array equal to TRUE.